Powerful PowerDesigner

다음과 같은 스크립트를 PowerDesigner 에서 적용하시면 아주 깔끔하게 Comment 의 내용을 테이블 및 컬럼명으로 복사(컨버전) 하실 수 있습니다.

Option Explicit

ValidationMode = True
InteractiveMode = im_Batch '대화 상자를 디스플레이하지 않고 항상 디폴트 값을 사용한다. 스크립트로 자동화작업을 할 때 지정

Dim mdl '현재 모델

'현재 활성화되어 있는 모델을 얻어온다.
Set mdl = ActiveModel

If (mdl Is Nothing) Then
 MsgBox "현재 활성화되어 있는 모델이 없습니다."
ElseIf ( Not mdl.IsKindOf(PdPDM.cls_Model) ) Then
 MsgBox "현재 모델은 물리 데이터 모델이 아닙니다."
Else
 ProcessFolder mdl
End If

Private Sub ProcessFolder(folder)

 On Error Resume Next

 Dim tbl '현재 실행중인 테이블
 For Each tbl In folder.tables
 
  If (Not tbl.IsShortcut) Then
   tbl.name = tbl.comment  
   Dim col '현재 테이블 컬럼
   For Each col In tbl.columns
    If col.comment = "" Then
    Else
     col.name = col.comment
    End If
   Next
  End If
 Next

 Dim view '현재 실행중인 뷰
 For Each view In folder.views
  If (Not view.IsShortcut) Then
   view.name = view.comment
  End If
 Next

 '하위 패키지에 대한 처리
 Dim f '현재 실행중인 폴더
 For Each f In folder.Packages
  If (Not f.IsShortcut) Then
   ProcessFolder f
  End If
 Next

End Sub